Conductance from Landauer-Buttiker approach

We reconstruct the original formula from the paper with dimensional units, as a result, an additional dimensionless coefficient $k$ appears in the formula, and the units of measurement of energy $\mathrm{eV}$ and the length of $\mathrm{nm}$.

ℏ = 1.054572*^-27; 
vf = 1*^8;
d0 = 1*^-7;
eV = 1.6021766208*^-12;
k = eV*d0/ℏ/vf;

T[x_, E0_, V_, d_] := ((E0 - V)^2 - E0^2 Sin[x]^2)/((E0 - V)^2 - 
  E0^2 Sin[x]^2 + V^2 Sin[k*d Sqrt[(E0 - V)^2 - E0^2 Sin[x]^2]]^2 Tan[x]^2)

DensityPlot[
 T[x, E0, .2, 30], {E0, -.1, .5}, {x, -π/2 + 10^-2, π/2 - 10^-2}, 
 PlotPoints -> 100, PerformanceGoal -> "Quality", PlotRange -> All, 
 FrameLabel -> {"E, eV", "θ"}, PlotLabel -> T]

G[E0_, V_, d_] := 
NIntegrate[Cos[x]*T[x, E0, V, d], {x, -Pi/2, Pi/2}, 
  Method -> "DoubleExponential", PrecisionGoal -> 8, 
  MinRecursion -> 4]   


lst = Table[{E0, G[E0, .2, 30]}, {E0, -1, 1.5, .001}];

ListLinePlot[lst, AxesLabel -> {"E, eV", "G"}]

The following is basically @Alex's answer, but making use of the units framework, and using a style more similar to the question.

First, define:

V = .2;
d = 30;

Next, determine the conversion factor using Ctrl-= to input the units (I used an image to see how it looks in a notebook):

(Alternatively, type in the FullForm equivalent):

conv = (Quantity["Electronvolts"]Quantity["Nanometers"])/(Quantity["ReducedPlanckConstant"]Quantity[10^8,"Centimeters"/"Seconds"])

1.5192675

(another shorter version that relies on Quantity interpretations)

Quantity["eV"] Quantity["nm"]/(Quantity["ℏ"] Quantity[10^8,"cm/s"])

1.519267

Then, define k and T:

k[e_, θ_] := Sqrt[(e-V)^2 - e^2 Sin[θ]^2]
T[e_,θ_] := (1 + V^2/k[e,θ]^2 Tan[θ]^2 Sin[k[e,θ] d conv]^2)^-1

Next, define G but restrict to only numeric arguments:

G[e_?NumericQ] := NIntegrate[T[e,θ] Cos[θ], {θ, -Pi/2, Pi/2}]

Finally, plot:

Plot[G[e], {e, -1, 1.5}, AxesOrigin->{0,0}]