EasterSunday replacement in Mathematica 10

For reference, here is a Mathematica implementation of this algorithm from an anonymous source, and reproduced in a number of other references (e.g. Meeus):

SetAttributes[easter, Listable];
easter[y_Integer] := Module[{y19 = Mod[y, 19], b, c, d, e, h, i, k, l},
       {b, c} = QuotientRemainder[y, 100];
       {d, e} = QuotientRemainder[b, 4]; {i, k} = QuotientRemainder[c, 4];
       h = Mod[19 y19 + b - d - Quotient[b + 1 - Quotient[b + 8, 25], 3] + 15, 30];
       l = Mod[2 e + 2 i - h - k + 32, 7];
       Prepend[QuotientRemainder[h + l - 7 Quotient[y19 + 11 (h + 2 l), 451] +
                                 114, 31] + {0, 1}, y]]

Test:

Table[DataPaclets`CalendarDataDump`EasterSunday[k], {k, 1950, 2000}] ===
easter[Range[1950, 2000]]
   True

---

As a belated bonus, here is a compact implementation of the computus for Greek Orthodox Easter, based on Meeus's version:

SetAttributes[easterGreek, Listable];
easterGreek[y_Integer] := Module[{p, q, r, u},
            {p, q, r} = Mod[y, {19, 7, 4}]; u = Mod[19 p + 16, 30];
            u = u + Mod[4 q + 2 r + 6 u, 7] + Quotient[y, 100] - Quotient[y, 400] - 12;
            {y, 4 + Boole[u > 30], Mod[u, 30, 1]}]

This should work for the years 1500-5100.

Another undocumented interface similar to the one in Michael E2's answer

Developer`CalendarData[{#}, "Easter"] & /@ Range[1950, 2050]

Also, while the Calendar package has been deprecated, it is still present in the layout, in other words it is still possible to use EasterSunday

Needs["Calendar`"]

EasterSunday /@ Range[1950, 2050]

DataPaclets`CalendarDataDump`EasterSunday /@ Range[1950, 2050]
DataPaclets`CalendarDataDump`EasterSundayGreekOrthodox /@ Range[1950, 2050]