Evaluating an integral over an elliptical disk

You've inconsistently put in/left out spaces, a b vs. ab. Also you need the assumption r > 0.

Integrate[((u v)/Sqrt[a b - h^2] - (h v^2)/(a b - h^2)) Boole[u^2 + v^2 <= r^2],
 {u, -r, r}, {v, -r, r}, 
 Assumptions -> {a > 0, a b - h^2 > 0, r > 0}]
(*  (h π r^4)/(4 (-a b + h^2))  *)

---

Using regions, which gives the answer the OP derived by hand:

Integrate[
 x y,
 {x, y} ∈ ImplicitRegion[a x^2 + 2 h x y + b y^2 <= r^2, {x, y}], 
 Assumptions -> {a > 0, a b - h^2 > 0, r > 0}]
(*  -((h π r^4)/(4 (a b - h^2)^(3/2)))  *)

---

Here's a way that might work in V7, but I cannot check. I relied on the form of cylindrical decomposition that Reduce returned, which in this case (of an ellipse) has a simple logical structure. (There is a way to deal with more complicated cylindrical decompositions that I've used elsewhere, but this was simpler and more easily understood.)

dom = Sequence @@ Cases[
   Reduce[
    a > 0 && a b - h^2 > 0 && r > 0 && a x^2 + 2 h x y + b y^2 < r^2,
    {x, y}, Reals],
   _[a_, ___, v : x | y, ___, b_] :> {v, a, b}, (* inequality to iterator *)
 Infinity]
(*
  Sequence[
   {x, -Sqrt[((b r^2)/(a b - h^2))], Sqrt[(b r^2)/(a b - h^2)]},
   {y, -((h x)/b) - Sqrt[(b r^2 - a b x^2 + h^2 x^2)/b^2],
     -((h x)/b) + Sqrt[(b r^2 - a b x^2 + h^2 x^2)/b^2]}
   ]
*)

Integrate[x y, dom, Assumptions -> {a > 0, a b - h^2 > 0, r > 0}]
(*  -((h π r^4)/(4 (a b - h^2)^(3/2)))  *)

Another substitution-free method:

Simplify[Integrate[x y, {x, y} ∈ Ellipsoid[{0, 0}, Inverse[{{a, h}, {h, b}}/r^2]]],
         a > 0 && b > 0 && r > 0 && a b > h^2]
   -((h π r^4)/(4 (a b - h^2)^(3/2)))