Exporting data from Excel into Mathematica using clipboard
You can easily implement it in two steps.
- You create an Excel macro in your personal.xlsb that you can use to execute some keybord shortcut to copy your selected data. I use CTRL+SHIFT+C.
- Second you can create a Mathematica function to import this clipboard data (optional, but very usefull)
More information on how to handle your personal.xlsb here
How to implement it!
Below we have the Excel macro to copy to clipboard the selected Excel range using Mathematica format:
Private Sub Excel_To_Mathematica()
'Program by: Dana DeLouis (Microsoft Excel MVP)
'Modified by: Rodrigo Murta (Mathematica Addicted)
'Changes by Murta:
' Usable for "," as decimal separator
' Eliminate bug for big and small Numbers
' Elminate Transpose line number limitations
Dim ClipBoard As New DataObject
Dim Nr As Long '# of Rows
Dim Nc As Long '# of Columns
Dim r As Long ' Row Pointer
Dim C As Long ' Column Pointer
Dim T() 'Temporary Storage
Dim Tc() 'Temporary Storage
Dim v As Variant 'Holds the data from Worksheet
Dim s As String
Dim ButtonClicked As Long
Const DQ As String = """" 'Double Quotes: 4 of them!
Dim transp 'Temp Array for Transpose Case
Application.ScreenUpdating = False
'// A little error checking first...
If TypeName(selection) <> "Range" Then
MsgBox "Select a Range first"
Exit Sub
End If
If selection.Areas.Count > 1 Then
MsgBox "Select only 1 area. Macro will Exit"
Exit Sub
End If
'// Load data into an Array
If selection.Cells.Count = 1 Then
ReDim v(1 To 1, 1 To 1)
v(1, 1) = selection
Else
v = selection
End If
'// Get number of Rows & Columns
Nr = UBound(v, 1)
Nc = UBound(v, 2)
If Nc = 1 And Nr > 1 Then
ButtonClicked = MsgBox("Transform Vectors in Columns?", vbYesNo)
End If
'// Put quotes around text
For r = 1 To Nr
For C = 1 To Nc
If IsNumeric(v(r, C)) Then
v(r, C) = Replace(Replace(Format(v(r, C), "@"), ",", "."), "@", "")
v(r, C) = Replace(v(r, C), "E", "*10^")
Else
v(r, C) = DQ & v(r, C) & DQ
End If
Next C
Next r
If ButtonClicked = vbYes Then
ReDim tempArray(1 To Nr)
For i = 1 To Nr
tempArray(i) = v(i, 1)
Next
v = tempArray
s = "{" & Join(v, ",") & "}"
Else
ReDim T(1 To Nr)
ReDim Tc(1 To Nc)
For r = 1 To Nr
For C = 1 To Nc
Tc(C) = v(r, C)
Next
T(r) = "{" & Join(Tc(), ",") & "}"
Next
s = Join(T, ",")
If Nr > 1 Then s = "{" & s & "}"
End If
ClipBoard.SetText s
ClipBoard.PutInClipboard
Application.ScreenUpdating = True
'Application.StatusBar = "data copied"
'Application.StatusBar = False
End Sub
Private Function TransposeDim(v As Variant) As Variant
' Custom Function to Transpose a 1-based array (v)
Dim x As Long, y As Long, Xupper As Long, Yupper As Long
Dim tempArray()
Xupper = UBound(v, 2)
Yupper = UBound(v, 1)
ReDim tempArray(1 To Xupper, 1 To Yupper)
For x = 1 To Xupper
For y = 1 To Yupper
tempArray(x, y) = v(y, x)
Next y
Next x
TransposeDim = tempArray
End Function
If you want, you can create the Excel shortcut using this command in your ThisWorkbook object of you personal.xlsb file:
Private Sub Workbook_Open()
Application.OnKey "^+c", "Excel_To_Mathematica" 'ctrl + shift + c
End Sub
Using the above macros, you are ok to past your data into Mathematica using CTRL+V, but some times, you have a big list, and you would like to make some variable to receive this information directly. So I use this Mathematica function my start up pack.
getClipboardData[]:= NotebookGet[ClipboardNotebook[]][[1, 1, 1]] // ToExpression
So, instead of CTRL+V my Excel data, I can write:
data = getClipboardData[]
I tested it 1M Excel lines without problems (that is the excel limit in 2010). I use Mathematica on Mac and Excel on Windows (using Parallels).
UPDATE
The code still works with Excel 2013
A very simple way to import tables of integers is like this:
add a few columns in Excel containing the separators "{", "," and "}," in between your columns of integers:
then paste in your workbook, and add a leading "{" and a trailing "}" and ... done.
(mind the superfluous comma at the end).
Works in version 10.
@Murta's method has served me well for several years now, but this seems to be broken under x64 Office installations in Windows 8+. For me (on Windows 10 x64 and Office 2016 x64), the routine places random unicode characters in the clipboard.
I've scoured the web and found a solution. Place the following code in the same Module as @Murta's routines.
Private Declare PtrSafe Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As LongPtr)
Private Declare PtrSafe Function GlobalUnlock Lib "kernel32" (ByVal hMem As LongLong) As Long
Private Declare PtrSafe Function GlobalLock Lib "kernel32" (ByVal hMem As LongLong) As LongPtr
Private Declare PtrSafe Function GlobalAlloc Lib "kernel32" (ByVal wFlags As Long, ByVal dwBytes As LongLong) As LongPtr
Private Declare PtrSafe Function GlobalSize Lib "kernel32" (ByVal hMem As LongPtr) As LongPtr
Private Declare PtrSafe Function CloseClipboard Lib "user32" () As Long
Private Declare PtrSafe Function OpenClipboard Lib "user32" (ByVal hwnd As LongLong) As Long
Private Declare PtrSafe Function EmptyClipboard Lib "user32" () As Long
Private Declare PtrSafe Function lstrcpy Lib "kernel32" Alias "lstrcpyA" (ByVal lpString1 As Any, ByVal lpString2 As String) As LongPtr
Private Declare PtrSafe Function GetClipboardData Lib "user32" (ByVal wFormat As Long) As LongPtr
Private Declare PtrSafe Function SetClipboardData Lib "user32" (ByVal wFormat As Long, ByVal hMem As LongLong) As LongLong
Private Declare PtrSafe Function EnumClipboardFormats Lib "user32" (ByVal wFormat As Long) As Long
Private Declare PtrSafe Function IsClipboardFormatAvailable Lib "user32" (ByVal wFormat As Long) As Long
Public Enum eCBFormat
CF_TEXT = 1
CF_BITMAP = 2
CF_METAFILEPICT = 3
CF_SYLK = 4
CF_DIF = 5
CF_TIFF = 6
CF_OEMTEXT = 7
CF_DIB = 8
CF_PALETTE = 9
CF_PENDATA = 10
CF_RIFF = 11
CF_WAVE = 12
CF_UNICODETEXT = 13
CF_ENHMETAFILE = 14
CF_HDROP = 15
CF_LOCALE = 16
CF_MAX = 17
CF_OWNERDISPLAY = &H80
CF_DSPTEXT = &H81
CF_DSPBITMAP = &H82
CF_DSPMETAFILEPICT = &H83
CF_DSPENHMETAFILE = &H8E
CF_PRIVATEFIRST = &H200
CF_PRIVATELAST = &H2FF
CF_GDIOBJFIRST = &H300
CF_GDIOBJLAST = &H3FF
End Enum
Const GHND = &H42
Public Function ClipBoard_HasFormat(ByVal phWnd As LongLong, ByVal peCBFormat As eCBFormat) As Boolean
Dim lRet As Long
If OpenClipboard(phWnd) > 0 Then
lRet = EnumClipboardFormats(0)
If lRet <> 0 Then
Do
If lRet = peCBFormat Then
ClipBoard_HasFormat = True
Exit Do
End If
lRet = EnumClipboardFormats(lRet)
Loop While lRet <> 0
End If
CloseClipboard
Else
'Problem: Cannot open clipboard
End If
End Function
Public Function ClipBoard_GetTextData(ByVal phWnd As LongLong) As String
Dim hData As LongPtr
Dim lByteLen As LongPtr
Dim lPointer As LongPtr
Dim lSize As LongLong
Dim lRet As Long
Dim abData() As Byte
Dim sText As String
lRet = OpenClipboard(phWnd)
If lRet > 0 Then
hData = GetClipboardData(eCBFormat.CF_TEXT)
If hData <> 0 Then
lByteLen = GlobalSize(hData)
lSize = GlobalSize(hData)
lPointer = GlobalLock(hData)
If lSize > 0 Then
ReDim abData(0 To CLng(lSize) - CLng(1)) As Byte
CopyMemory abData(0), ByVal lPointer, lSize
GlobalUnlock hData
sText = StrConv(abData, vbUnicode)
End If
Else
'Problem: Cannot open clipboard
End If
CloseClipboard
End If
ClipBoard_GetTextData = sText
End Function
Public Function ClipBoard_SetData(psData As String) As Boolean
Dim hGlobalMemory As LongLong
Dim lpGlobalMemory As LongPtr
Dim hClipMemory As LongLong
Dim fOK As Boolean
fOK = True
' Allocate moveable global memory.
hGlobalMemory = GlobalAlloc(GHND, LenB(psData) + 1)
If hGlobalMemory = 0 Then
Exit Function
End If
' Lock the block to get a far pointer
' to this memory.
lpGlobalMemory = GlobalLock(hGlobalMemory)
' Copy the string to this global memory.
lpGlobalMemory = lstrcpy(lpGlobalMemory, psData)
' Unlock the memory.
If GlobalUnlock(hGlobalMemory) <> 0 Then
fOK = False
GoTo OutOfHere2
End If
' Open the Clipboard to copy data to.
If OpenClipboard(0&) = 0 Then
fOK = False
Exit Function
End If
' Clear the Clipboard.
Call EmptyClipboard
' Copy the data to the Clipboard.
hClipMemory = SetClipboardData(eCBFormat.CF_TEXT, hGlobalMemory)
OutOfHere2:
Call CloseClipboard
ClipBoard_SetData = fOK
End Function
Then change Murta's function to include ClipBoard_SetData (s) instead of
ClipBoard.SetText s
ClipBoard.PutInClipboard
References: 1, 2