gradle jacocoTestReport is not working?

Following helped . its in samples/testing/jacaco of gradle-2.3-all.zip from https://gradle.org/releases/

apply plugin: "java"

apply plugin: "jacoco"

jacoco {
    toolVersion = "0.7.1.201405082137"
    reportsDir = file("$buildDir/customJacocoReportDir")
}

repositories {
    mavenCentral()
}

dependencies {
    testCompile "junit:junit:4.+"
}

test {
    jacoco {
        append = false
        destinationFile = file("$buildDir/jacoco/jacocoTest.exec")
        classDumpFile = file("$buildDir/jacoco/classpathdumps")
    }
}


jacocoTestReport {
    reports {
        xml.enabled false
        csv.enabled false
        html.destination "${buildDir}/jacocoHtml"
    }
}

Unfortunately, none of these answers worked for me.

I had a similar issue.
Only different in not having the exec file generated.
And because of that , I found that the jacocoTestReport was simply "skipped".

I got it fixed by adding :

apply plugin: 'jacoco'

test {
  useJUnitPlatform()
  finalizedBy jacocoTestReport // report is always generated after tests run
}

jacocoTestReport {
    ...
    ...
    ...
    ...
}

That's because I'm using Junit5 with spring boot 2.X

You don't have to configure reportsDir/destinationFile

Because jacoco has default values for them.

build.gradle:

plugins {
    id 'java'
    id 'jacoco'
}

jacocoTestReport {
    reports {
        xml.enabled true
        html.enabled true
        csv.enabled true
    }
}

repositories {
    jcenter()
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.12'
}

Run gradle test jacocoTestReport

You can find the test report in ./build/reports/jacoco/test directory.

HTML output is in ./build/reports/jacoco/test/html directory.