How to disable hover tooltip on tabs

2019 anybody? (Works on both Chrome and Chromium btw)

1. Go to chrome://flags

2. Search for "Hover"

3. Set "Tab Hover Cards" to "Disabled"

4. Restart Chrome

You cannot disable these tooltips in Chrome.

Via: http://productforums.google.com/forum/#!topic/chrome/ygoNhTB5K1Y https://groups.google.com/forum/#!topic/chromebook-central/gxAnZM-2tpM http://forums.mozillazine.org/viewtopic.php?f=7&t=1562905

I couldn’t get the idea of a program moving the cursor for you out of my mind, so I threw one together.

Below is an AutoHotkey script (which can be compiled to a standalone executable if desired) that detects when the mouse cursor has remained idle near the top of a Chrome window for a while and if so, moves it to the lower-right corner of the screen.

It works as expected and prevents tooltips from popping up, but because of the staggered timing (the subroutine triggering and the tooltip countdown), sometimes the tooltip pops up for a split second before the cursor is moved. This can be reduced by decreasing the timer (the tip variable).

I’m also thinking about enhancing the script by handling the timer manually instead of using AutoHotkey’s timer. That way, it can count down from the last time that the mouse was moved or button pressed instead of just every x seconds regardless.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   MoveIdleMouse.ahk
;
; Prevents tooltips from being annoying in Chrome by detecting
; when the mouse is idle while near the top of a Chrome window
; and then moving it to the bottom-right corner of the screen.
;
; https://superuser.com/questions/393738/
;
;   (cl) 2013- Synetech inc., Alec Soroudi
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

#SingleInstance force
#Persistent

; Read the tooltip delay from the registry (this is the amount of time the
; cursor has to hover over something in order to trigger the tooltip)
RegRead, tip, HKCU, Control Panel\Mouse, MouseHoverTime

; Divide it by two to accommodate staggared timing. Adjust as desired.
;tip:=tip/2

; Set specified subroutine to run every so often (before tooltip triggered)
SetTimer, CheckCursor, %tip%

; Get the current mouse cursor position to compare to during first interval
MouseGetPos, x1, y1
return

; This subroutine checks the current cursor position and moves if idle
CheckCursor:
  ; First check if the cursor is over a Chrome window; ignore if not
  IfWinNotActive, ahk_class Chrome_WidgetWin_0
    return

  ; Next, check if any buttons are pressed and ignore if so
  if (GetKeyState("LButton") or GetKeyState("RButton") or GetKeyState("MButton")
      or GetKeyState("XButton1") or GetKeyState("XButton2"))
    return

  ; Get the current mouse position and check if it is both unchanged, and
  ; near the top of Chrome (position is relative to window by default)
  MouseGetPos, x2, y2
  If (((x1 = x2) and (y1 = y2))  and  ((y2 >= 0) and (y2 <= 27)))
  {
    ; Move the cursor to the bottom-right corner of the screen immediately
    ; You can adjust destination position as desired
    MouseMove, A_ScreenWidth+3, A_ScreenHeight+3, 0
  }
  else {
    ; Update current cursor position to compare to during the next interval
    x1 := x2
    y1 := y2
  }
  return