How to make an Epilog moveable with drag and drop

Related: 14556 and 7547

Using Locator to give you the control you are seeking :

Manipulate[
 Plot[Sin[a*x] - .3, {x, -3, 3}, Epilog -> {Dynamic[If[t,
      Locator[Dynamic[pt], 
       Framed[Pane[
         "I want the user to have the abilty to move this box \
anywhere
         inside this white area so the user can see what's behind \
it.", 70], Background -> LightBlue, RoundingRadius -> 4, 
        BaseStyle -> Gray],
       Background -> White, ImageSize -> 150], {}]]}],

 {a, 1, 10},
 {{t, True, "Hide/Show Notes"}, {True, False}},
 {pt, Scaled[{0.5, 0.5}], None}
 ]

Manipulate[Plot[Sin[a x] - .3, {x, -3, 3}, Epilog ->  Dynamic@Inset[If[t, Framed[
       Pane["I want the user to have the abilty to move this box \
anywhere
        inside this white area so the user can see what's behind it.",
         70], Background -> LightBlue, RoundingRadius -> 4, 
       BaseStyle -> Gray], ""], loc, Center]], 
 {a, 1, 10}, 
 {{t, True, "Hide/Show Notes"}, {True, False}}, 
 {{loc, {1, 1}}, {-3, -2}, {3, 1}, ControlType -> Locator, Appearance -> None}]