How to remove YAML frontmatter from markdown files?

I understand your question to mean that you want to remove the first ----enclosed block if it starts at the first line. In that case,

sed '1 { /^---/ { :a N; /\n---/! ba; d} }' filename

This is:

1 {              # in the first line
  /^---/ {       # if it starts with ---
    :a           # jump label for looping
    N            # fetch the next line, append to pattern space
    /\n---/! ba; # if the result does not contain \n--- (that is, if the last
                 # fetched line does not begin with ---), go back to :a
    d            # then delete the whole thing.
  }
}
                 # otherwise drop off the end here and do the default (print
                 # the line)

Depending on how you want to handle lines that begin with ---abc or so, you may have to change the patterns a little (perhaps add $ at the end to only match when the whole line is ---). I'm a bit unclear on your precise requirements there.

If you don't mind the "or something" being perl.

Simply print after two instances of "---" have been found:

perl -ne 'if ($i > 1) { print } else { /^---/ && $i++ }' yaml

or a bit shorter if you don't mind abusing ?: for flow control:

perl -ne '$i > 1 ? print : /^---/ && $i++' yaml

Be sure to include -i if you want to replace inline.

If you want to remove only the front matter, you could simply run:

sed '1{/^---$/!q;};1,/^---$/d' infile

If the first line doesn't match ---, sed will quit; else it will delete everything from the 1st line up to (and including) the next line matching --- (i.e. the entire front matter).