Geodesics on the twisted pseudosphere (Dini's surface)

To answer Joseph's questions:

First, it's not impossible to integrate the geodesic flow of the hyperbolic plane in these coordinates, but the formulae I got aren't very nice, so I'm not going to type them in unless I can find a better way to express them. It's probably easier than I got on a first pass through, but I don't have time to work on simplifying them right now.

Added note: (It helps to sleep on a problem sometimes.) If you set $a = r\cos t>0$ and $b=r\sin t>0$ and make the change of variables $$ v=\arcsin\bigl((\tan t)(\tan \theta)\bigr) \qquad\text{and}\qquad u= \frac{\log\rho - f(\theta)}{\sin t} $$ where $0<\theta< \tfrac12\pi{-}t$ and $0 < \rho < \infty$ and where $f$ (an elementary function, but not a nice one, apparently) is defined on $0<\theta<\tfrac12\pi{-}t$ so that $$ f'(\theta) = \frac{\sqrt{\cos^2 t - \sin^2\theta}}{\sin\theta}, $$ then the induced metric on the lower nappe of the surface (which is what Joseph drew) becomes $$ ds^2 = r^2\left(\frac{d\rho^2 + \rho^2 d\theta^2}{\rho^2\cos^2\theta}\right) = r^2\left(\frac{dx^2 + dy^2}{x^2}\right), $$ where $x = \rho\cos\theta$ and $y = \rho\sin\theta$. Now everything, including integrating the geodesics, is obvious.

Second, there does indeed exist a geodesic (and only one) that starts at any given point on the rim and spirals down the surface towards $z = -\infty$, i.e., it starts at a given $(u_0,v_0)=(u_0,\pi/2)$ and goes into the part of the surface with $0<v<\pi/2$. There's also one that starts at the same point and spirals up the surface towards $z=+\infty$, i.e., it starts at a given $(u_0,v_0)=(u_0,\pi/2)$ and goes into the part of the surface with $\pi/2<v<\pi$. (As j.c. has also noted, the given parametrization is not an immersion along $v=\pi/2$, but has a cusp singularity along the rim.)

I'm not good a drawing computer pictures, but here is a description of what you get when you develop the region $0<v<\pi/2$ into the hyperbolic plane with curvature $K=-1/(a^2+b^2)$ with $b\not=0$: First, the rim $v=\pi/2$ maps to a curve $C$ with geodesic curvature $\kappa=-a/(a^2+b^2)$. Of course, this curve meets the circle at infinity (i.e., the ideal boundary) at two distinct points $P_+$ (as $u\to+\infty$) and $P_-$ (as $u\to-\infty$). If you let $L$ be the actual geodesic that also has $P_+$ and $P_-$ as endpoints, then the developing map carries the region $0<v<\pi/2$ into the region $R$ of the hyperbolic plane that fits between $C$ and $L$. The curves $v=v_0$ for $0<v_0<\pi/2$ are just the other constant curvature curves in $R$ that join $P_-$ to $P_+$. Each of the curves $u=u_0$ then maps to a curve that is asymptotic to the geodesic $L$, but comes up and touches the curve $C$ while making a cusp there at $(u_0,\pi/2)$. (The part $\pi/2<v<\pi$ just covers $R$ again, so, all told, the strip $0<v<\pi$ covers $R$ twice, folding along $v=\pi/2$ and mapping this fold onto $C$.)

Now, if you take the geodesic ray in the hyperbolic plane that joins the developed image of $(u_0,\pi/2)$ (on $C$) to the ideal point $P_-$, then this corresponds to a geodesic on the Dini surface that spirals down to $z=-\infty$. Similarly if you take the geodesic ray in the hyperbolic plane that joins the developed image of $(u_0,\pi/2)$ (on $C$) to the ideal point $P_+$, then this corresponds to a geodesic on the Dini surface that spirals up to $z=+\infty$.

Since Joseph asked for pictures, I will add to Robert's excellent response with the following images.

For the purposes of implementing Robert's change of variables in Mathematica, I simplified the composition as shown below:

(*twist parameter*)
t = Pi/6;

(*auxiliary function*)

g[x_, y_] := Sqrt[x^2 - y^2 + (x^2 + y^2)*Cos[2*t]];

(*change of variables for u*)

u[x_, y_] := 
  Csc[t]*(Log[x^2 + y^2] - 
     Log[Sqrt[2]*x + 
       g[x, y]] + (Cos[t]*
        Log[(-(x*Sqrt[1 + Cos[2*t]]) - 
            g[x, y])/(-(x*Sqrt[1 + Cos[2*t]]) + g[x, y])])/2);

(*parameterization*)

r[x_, y_] := {Sin[t]*Cos[u[x, y]]*y/x, Sin[t]*Sin[u[x, y]]*y/x, 
   Cos[t]*(Sqrt[1 - Tan[t]^2*y^2/x^2] + 
       Log[(Tan[t]*y/x)/(1 + Sqrt[1 - Tan[t]^2*y^2/x^2])]) + 
    u[x, y]*Sin[t]};

The domain of r[x,y] is the region where $y\geq0$, $x\geq y\tan t$. This parameterization is an isometry from its domain (endowed with the Poincare half-space model metric) to its image.

First, here is an image of the parameterized surface using Mathematica's standard mesh function

r1 = 1; r2 = 10; ParametricPlot3D[r[x, y], {x, 0, r2}, {y, 0, r2}, 
 RegionFunction -> 
  Function[{a, b, c, x, y}, 
   x >= Tan[t]*y && r1^2 <= x^2 + y^2 <= r2^2], PlotPoints -> 100]

Next, let's visualize some geodesics. Below we show some geodesics in the half-plane model and their images under the parameterization.

(*parameter for paths*)
rad = 1;

(*Geodesics in half-plane model*)
path1[x_] := {x, Cos[t]*rad};
path2[th_] := {rad*Cos[th], rad*Sin[th]};
path3[th_] := rad*Sin[t]/Sin[2 t]*{Cos[th], Sin[th] + 1};

(*Show geodesics in half-plane model with domain*)
Show[
 RegionPlot[domain, {x, 0, 10}, {y, 0, 10}, ImageSize -> Medium, 
  PlotStyle -> GrayLevel[0.9], BoundaryStyle -> None],
 ParametricPlot[path1[x], {x, Tan[t]*rad, 10}, PlotStyle -> Red],
 ParametricPlot[path2[th], {th, 0, Pi/2 - t}, PlotStyle -> Green],
 ParametricPlot[path3[th], {th, -Pi/2, Pi/2 - 2 t}, 
  PlotStyle -> Blue]
 ]

Now, those same three geodesics mapped onto Dini's Surface.

Show[
 ParametricPlot3D[r[x, y], {x, 0, 10}, {y, 0, 10}, 
  RegionFunction -> Function[{a, b, c, x, y}, domain], 
  PlotPoints -> 100, Mesh -> False, PlotStyle -> Opacity[0.5], 
  PlotRange -> {{-1, 1}, {-1, 1}, {-4, 4}}],
 ParametricPlot3D[r @@ path1[x], {x, Tan[t]*rad, 10}, 
  PlotStyle -> Red],
 ParametricPlot3D[r @@ path2[th], {th, 0, Pi/2 - t}, 
  PlotStyle -> Green],
 ParametricPlot3D[r @@ path3[th], {th, -Pi/2, Pi/2 - 2 t}, 
  PlotStyle -> Blue]
 ]

The blue geodesic seems to be what Joseph was imagining in the first place, following the surface to $z=-\infty$ and getting ever closer to the $z$-axis. The green geodesic leaves the rim at a right angle and follows the shortest path to the $z$-axis. Finally, most surprising to me anyway, is the red geodesic, which winds up the surface to $z=\infty$.