How to obtain the list of all environment variables in Vim?

The previous answers have been made obsolescent by the vimscript environ() function.

For example, to list them all in order:

:let evars = environ()
:for var in evars->keys()->sort()
:    echo var . '=' . evars[var]
:endfor

To list all environment variables, use

:echo $<C-D>

Then, you can start typing the name of the variable of interest, auto-complete with Tab, finally press Enter to show its value.

You didn't tell whether you need this interactively or in a script. For the latter, it's unfortunately not possible to capture the output via :redir.

Looking at the other anwers, you can do it without a script.

Enter insert mode, and then press

<C-R>=

Where Ctrl+R allows you to insert any of the registers available (see :help i_Ctrl-R). But particularly you'll use the expression register = here to evaluate a string (see :help @=).

So, now you can insert the expression introduced by ib.'s answer. Enter this:

$<C-A>"<HOME>"<CR><ESC>

Now, you should be back to normal mode and the expression should have evaluated to a string and been placed in the buffer. You can further clean it up with a substitute command:

:s/\s/\r$/g

That should place every environment variable on a different line.

In Vimscript, there is not a direct way of getting the list of currently defined environment variables. However, it is possible to exploit Vim command-line completion feature to make one.

Consider possible completions for the following unfinished command:

:echo $

It is not difficult to see that, according to Vimscript syntax, the completions must be the names of the environment variables. Pressing the wildchar key (Tab, by default) or Ctrl+D will display all of them.

In order to get this list of completions from within a script, we need to overcome its interactive nature. A possible trick that I propose herein relies on a combination of features. The first of them is the Ctrl+A command. In Command-line mode, this shortcut triggers insertion of every available completion in front of the cursor. The inserted completions are listed in alphabetical order and separated with spaces.

If we could make Vim print those completions out right into the command line, we would easily capture them by redirecting command output with the :redir command. But all we need to achieve that side effect is to quote the text inserted with Ctrl+A: Quoting makes the rest of our :echo command a string literal that can be just printed out!

:echo 'NAME1 NAME2 NAME3'
NAME1 NAME2 NAME3

To edit the command line in this way, the user can type :ec (an alias for :echo) followed by $, press Ctrl+A, type ', jump to the beginning of the line by pressing Ctrl+B, move the cursor over the dollar sign by pressing ⇾ (the right arrow key) twice, delete that $, and, finally, insert ' instead. The same sequence of key presses can easily be reproduced non-interactively using the :normal command.

Putting all these pieces together, we obtain the following function:

function! Env()
    redir => s
    sil! exe "norm!:ec$\<c-a>'\<c-b>\<right>\<right>\<del>'\<cr>"
    redir END
    return split(s)
endfunction

For this approach to work, Vim must be compiled with the +cmdline_compl feature.