Path Names Longer Than 256 on Windows

With a few rare exceptions, Mathematica is generally unable to work with long path names on Windows. This response presents two strategies to work around this difficulty: extended-length path syntax and short path names (documented in Naming Files, Paths, and Namespaces from the Windows Dev Center).

Let's start with a big file name:

$big = "034567890345678903456789034567890345678903456789034567890345678903456789034567890345678903456789034567890345678903456789034567890345678903456789034567890345678903456789034567890345678903456789034567890345678903456789034567890345678903456789034567890";

Extended-length Path Syntax

The Windows echo command cannot handle this big name:

Run["cmd /c echo hello >", $big]
(* 1 *)   (* i.e. "error" *)

It can, however, handle extended-length path syntax (in recent versions of Windows). This entails tacking the prefix \\?\ onto the front of an absolute pathname. We will use some helper functions:

$longPrefix = "\\\\?\\";

toLongPath[filename_] := $longPrefix <> ExpandFileName[filename]

fromLongPath[filename_] := StringReplace[filename, StartOfString~~$longPrefix -> ""]

Usage:

toLongPath[$big]
(* \\?\C:\Users\wreach\Documents\03456789...9034567890 *)

fromLongPath[%]
(* C:\Users\wreach\Documents\03456789...9034567890 *)

The Windows echo command accepts this syntax:

Run["cmd /c echo hello >", toLongPath[$big]]
(* 0 *)   (* i.e. "success" *)

FirstCase[FileNames[], n_ /; StringLength[n] > 200]
(* "03456789034567890345...789034567890" *)

The Mathematica CopyFile function will also accept this syntax:

CopyFile[toLongPath[$big], "zot"];
FilePrint["zot"]
(* hello *)

DeleteFile["zot"]

Short Path Names

Unfortunately, FilePrint does not support extended-length path syntax:

FilePrint[toLongPath[$big]]
(* Cannot open \\?\C:\Users\wreach\Documents\03456...890. >> *)

We will switch to the second strategy: short path names. These are alternative names that Windows provides for use by DOS-like components (read: most of the Windows ecosystem). We can view short path names for files by using the Windows dir /x command:

Import["!cmd /c dir /x 03456*", "Text"]

(* ...
   Directory of C:\Users\wreach\Documents
   ...
   2015-10-24  14:33     8    034567~1     034567890...3456789034567890
   ...
*)

The directory listing shows us that the short file name for $big is 034567~1.

FilePrint["034567~1"]
(* hello *)

It would be nice to obtain such names programmatically. Alas, Mathematica does not have a built-in function to obtain short file names. We will use NETLink to call the Win32 API function GetShortPathName:

Needs["NETLink`"]
InstallNET[];

getLastError = DefineDLLFunction["GetLastError", "kernel32.dll", "DWORD", {}];

getShortPathNameW =
  DefineDLLFunction["GetShortPathNameW"
  , "kernel32.dll", "DWORD", {"LPCTSTR", "System.Text.StringBuilder", "DWORD"}
  , MarshalStringsAs -> "Unicode"
  ];

shortPath[name_String] :=
  NETBlock @ Module[{result = NETNew["System.Text.StringBuilder", 260]}
  , getShortPathNameW[toLongPath@name, result, result@Capacity]
  ; getLastError[] /. 0 :> fromLongPath@result@ToString[]
  ]

Here is our helper function in action:

shortPath[$big]
(* C:\Users\wreach\DOCUME~1\034567~1 *)

This short path can be used everywhere in Mathematica, including FilePrint:

FilePrint[shortPath[$big]]
(* hello *)

Such short paths can also be used by all of the components that support Mathematica, whether they be DLLs, Java, command line tools or anything else.

Note that short paths can only be obtained for files that already exist. This mechanism cannot be used to create new files with big names.

Incidentally, DeleteFile is one of the few functions that accepts extended-length path syntax:

DeleteFile[toLongPath[$big]]

(An addition to the great answer by WReach above.)

At least starting from version 11.3 Mathematica has built-in way to obtain short filenames using undocumented function FileInformation:

Export["Тест.txt", ""]
FileInformation["Тест.txt", "AbsoluteShortFileName"]

"Тест.txt"

"D:\\DOCUME~1\\47BB~1.TXT"

(thanks to GenericAccountName for the info).

Also starting from version 12.0.0 there is an under-documented (but "official") way to obtain the short path:

Information[File["Тест.txt"], "Properties"] // Shallow

{"ObjectType", "FileName", "DirectoryName", "AbsoluteFileName", "AbsoluteShortFileName", "ShortFileName", "FileBaseName", "FileExtension", "CreationDate", "LastAccessDate", <<33>>}

Information[File["Тест.txt"], "AbsoluteShortFileName"]

"D:\\DOCUME~1\\47BB~1.TXT"