List of Recently Opened Files

Try

FE`Evaluate[FEPrivate`GetPopupList["MenuListNotebooksMenu"]]

It works in my machine :)

Then you may try something like this to open the notebooks:

ActionMenu["Open History", 
 Rest@FE`Evaluate[FEPrivate`GetPopupList["MenuListNotebooksMenu"]] /. 
  HoldPattern[a_ -> b_] :> (a :> NotebookOpen[$HomeDirectory <> b])]

---

Edit

The following will open the notebooks, notwithstanding the directory where they are stored:

k[n_] := FrontEndExecute[FrontEndToken["OpenFromNotebooksMenu", n]]

ActionMenu["Open History", 
           MapIndexed[#1 :> Unevaluated@k@#2[[1]] &, 
           Reverse@Rest[FE`Evaluate[FEPrivate`GetPopupList["MenuListNotebooksMenu"]]]
                                                                         [[All, 1]]]]

This gives the recently opened files as a list of rules:

Lookup[Options@$FrontEnd, NotebooksMenu]

Just the file names:

First /@ Lookup[Options@$FrontEnd, NotebooksMenu]

FileNameJoin instead of FrontEnd`FileName: (only tested on windows)

FileNameJoin[(Append @@ ((First@Last[#])[[;; 2]]))[[2 ;;]]] & /@ Lookup[Options@$FrontEnd, NotebooksMenu]