Typesetting a double Over Dot on top of a symbol

Use ToBoxes to find the boxes generated for OverDot[x, 2]:

OverDot[x,2] //ToBoxes

OverscriptBox["x", "¨"]

You can reproduce these boxes using Overscript:

Overscript[x, RawBoxes @ "¨"]

You can use the same approach for triple dots:

Overscript[x, RawBoxes @ "\[TripleDot]"]

For more dots, you will have to use a different mechanism to generate the dots, e.g.:

Overscript[x, Style[Row[{".",".",".","."}],FontTracking->"Condensed"]]

Update

You could also overload OverDot to work with the 3 and higher versions (I also included @Michael's syntax information fix):

SyntaxInformation[OverDot] = {"ArgumentsPattern" -> {_, _.}};
MakeBoxes[OverDot[a_, n_Integer?(GreaterThan[2])], StandardForm] := If[n==3,
    OverscriptBox[MakeBoxes[a], "\[TripleDot]"],
    OverscriptBox[
        MakeBoxes[a],
        ToBoxes @ Style[Row[ConstantArray[".", n]], FontTracking->"Condensed"]
    ]
]

Then:

You could fix the syntax highlighting, or ignore it. Here's a fix:

SyntaxInformation[OverDot] = {"ArgumentsPattern" -> {_, _.}};

Go to the Basic math assistant palette and click on the template.