excel vba check if specific bits set in longlong integer code example

Example 1: vba test if particular bits set in longlong integer

'Fast VBA function to test if specific bits are set 
'within a 64-bit LongLong integer. If ALL specified bits are set then 
'this function returns True. If ANY of the specified bits are
'not set then this function returns False.

'Bits are numbered from 0 to 63, so the first (least significant) bit
'is bit 0.

'Note: bits can be specified in any order.
'Note: any number of bits can be specified in one call.
'Note: the LongLong data type is only available in 64-bit VBA.


Function LongLongBitsAreSet(theLongLong^, ParamArray bits()) As Boolean
    Static i&, b^()
    If UBound(bits) = -1 Then Exit Function
    If (Not Not b) = 0 Then
        ReDim b(0 To 62)
        For i = 0 To 62
            b(i) = 2 ^ i
        Next
    End If
    For i = 0 To UBound(bits)
        If bits(i) < 0 Then Exit Function
        If bits(i) > 62 Then Exit Function
        If (theLongLong And b(Int(bits(i)))) = 0 Then Exit Function
    Next
    LongLongBitsAreSet = True
End Function


'----------------------------------------------------------------------------------------------------------------------------------------------------------------------
MsgBox LongLongBitsAreSet(255, 7)                    '<--displays: True                   255 = 00000000 00000000 00000000 00000000 00000000 00000000 00000000 11111111
MsgBox LongLongBitsAreSet(230, 0)                    '<--displays: False                  230 = 00000000 00000000 00000000 00000000 00000000 00000000 00000000 11100110
MsgBox LongLongBitsAreSet(85, 0, 2, 6, 4)            '<--displays: True                    85 = 00000000 00000000 00000000 00000000 00000000 00000000 00000000 01010101
MsgBox LongLongBitsAreSet(85, 0, 2, 5, 4)            '<--displays: False                   85 = 00000000 00000000 00000000 00000000 00000000 00000000 00000000 01010101
MsgBox LongLongBitsAreSet(485, 2, 7, 5)              '<--displays: True                   485 = 00000000 00000000 00000000 00000000 00000000 00000000 00000001 11100101
MsgBox LongLongBitsAreSet(24585, 14, 13, 3)          '<--displays: True                 24585 = 00000000 00000000 00000000 00000000 00000000 00000000 01100000 00001001
MsgBox LongLongBitsAreSet(&H7D12EACB, 24, 26, 30, 7) '<--displays: True            2098391755 = 00000000 00000000 00000000 00000000 01111101 00010010 11101010 11001011
MsgBox LongLongBitsAreSet(2 ^ 62 + 1, 62, 0)         '<--displays: True   4611686018427387905 = 01000000 00000000 00000000 00000000 00000000 00000000 00000000 00000001 
'
'
'

Example 2: excel vba are bits set in integer

'Fast VBA function to test if specific bits are set 
'within a 16-bit Integer. If ALL specified bits are set then 
'this function returns True. If ANY of the specified bits are
'not set then this function returns False.

'Bits are numbered from 0 to 15, so the first (least significant) bit
'is bit 0.

'Note: bits can be specified in any order.
'Note: any number of bits can be specified in one call.


Function IntegerBitsAreSet(theInteger%, ParamArray bits()) As Boolean
    Static i&, b%()
    If UBound(bits) = -1 Then Exit Function
    If (Not Not b) = 0 Then
        ReDim b(0 To 14)
        For i = 0 To 14
            b(i) = 2 ^ i
        Next
    End If
    For i = 0 To UBound(bits)
        If bits(i) < 0 Then Exit Function
        If bits(i) > 14 Then Exit Function
        If (theInteger And b(Int(bits(i)))) = 0 Then Exit Function
    Next
    IntegerBitsAreSet = True
End Function


'----------------------------------------------------------------------------------------
MsgBox IntegerBitsAreSet(255, 7)           '<--displays: True     255 = 00000000 11111111
MsgBox IntegerBitsAreSet(230, 0)           '<--displays: False    230 = 00000000 11100110
MsgBox IntegerBitsAreSet(85, 0, 2, 6, 4)   '<--displays: True      85 = 00000000 01010101
MsgBox IntegerBitsAreSet(85, 0, 2, 5, 4)   '<--displays: False     85 = 00000000 01010101
MsgBox IntegerBitsAreSet(485, 2, 7, 5)     '<--displays: True     485 = 00000001 11100101
MsgBox IntegerBitsAreSet(24585, 14, 13, 3) '<--displays: True   24585 = 01100000 00001001        
'
'
'

Example 3: xl vba is specific bit set in longlong integer

'Extremely fast VBA function to test if a specified bit is set 
'within a 64-bit LongLong integer.

'Bits are numbered from 0 to 63, so the first (least significant) bit
'is bit 0.

'Note: we do not inspect bit 63, the sign bit.
'Note: the LongLong data type is only available in 64-bit VBA.


Function LongLongBitIsSet(theLongLong^, bit As Byte) As Boolean
    Static i&, b^()
    If (Not Not b) = 0 Then
        ReDim b(0 To 62)
        For i = 0 To 62
            b(i) = 2 ^ i
        Next
    End If
    If bit < 63 Then LongLongBitIsSet = theLongLong And b(bit)
End Function


'------------------------------------------------------------------
MsgBox LongBitIsSet(255, 7)                       '<--displays: True
MsgBox LongBitIsSet(230, 0)                       '<--displays: False
MsgBox LongBitIsSet(16384, 14)                    '<--displays: True
MsgBox LongBitIsSet(-16383, 0)                    '<--displays: True
MsgBox LongBitIsSet(&H7FFFFFFF, 0), 0)            '<--displays: True
MsgBox LongLongBitIsSet(&H7FFFFFFFFFFFFFff^, 62)  '<--displays: True
'
'
'

Tags:

Vb Example

Recent Posts